Defining categorical response lists

To define a question with a predefined set of possible responses, place the following statement in the metadata section of the interview script:

<question_name> "<text>" categorical [[<number_of_choices>]]
{ <response_name_1> ["<response_text_1>"],
...
<response_name_n> ["<response_text_n>"]
};

A single number or a range specifying the number of responses that might be chosen from the list. If you omit this parameter, respondents might leave the question unanswered.

A categorical response list xan contain any number of responses. Respondents can select any number of responses and all the chosen responses are written to the case data, and are correctly processed by UNICOM Intelligence Reporter - Survey Tabulation. However, the SPSS MR OLE DB provider (mrOleDB.2) can return only the first 200 categories, so if you have an application that accesses the data using this provider, you might lose data if respondents have chosen more than 200 responses for a question.

Each response has a name and a response text. The response text (referred to as the label) is the text of the response as you want it to appear during the interview. It can contain any combination of letters, numbers, punctuation, and other characters. Depending on the response’s name, you might be able to omit the response text from the definition and display the response name instead.

The response name identifies the response. It must start with a letter or _ (underscore). The rest of the name can contain letters, numbers, or _ (underscore). If the response text is a single word that satisfies the criteria for a response name, you can define only a response name, and the interviewing program and the printed questionnaire will display this as the response text.

Here is an example of a question with a single-choice response list. The question text has been split across two lines for display purposes only. When you type question texts, type them all on one line with no line breaks:

LastEatOut "And the last time you ate out
  what type of restaurant did you go to?" categorical [1..1]
{
  Indian,
  Chinese,
  Greek,
  Italian,
  English,
  WestIndian "West Indian",
  French,
  Thai,
  Japanese,
  Spanish,
  Turkish,
  Other
};

▪The West Indian response has a response name and a response text because the text you want to display consists of two words. None of the other responses contains spaces or any other special characters so you need only specify the response name.

▪Each response is shown on a separate line. This is the standard way that UNICOM Intelligence Professional displays interview scripts. You can type more than one response on a line and, in some instances, the documentation shows response lists in this format if this allows a complete example to displayed on one page. However, when you close and reopen an interview script, response lists are always shown as in this example.

▪This example contains a simple Other response that respondents who went to a different type of restaurant can select. It is not a special Other Specify response that automatically prompts the user to enter an associated text response. For more information about Other Specify responses, see Other Specify.

▪The [1..1] identifies this as a single-choice response list. This means that the responses are displayed with radio buttons during the interview and respondents can select only one answer from the list. If you omit this parameter, respondents can leave the question unanswered. You can abbreviate the number of responses required for single-choice response lists to [1], but when you close and reopen the file, this converts to [1..1].

Here is another example that illustrates a situation when you must always define response names and response texts. Most of the response texts you want to display start with a number. Response names cannot start with numbers so you must choose different names for each response:

ChildAge "How old are your children?" categorical [1..]
{
YUnder1 "Under 1 Year",
Y3_5 "3-5 Years",
Y6_12 "6-12 Years",
Y13_16 "13-16 Years",
Y17_18 "17-18 Years",
Y19_21 "19-21 Years",
YAdult "Over 21 Years"
};

To use a double quotation mark in a question or response text, type it as:

so that it is not interpreted as a quotation mark that encloses text.

When the respondent must choose a fixed number of responses, type that number enclosed in square brackets. The interviewing program will not allow respondents to move to the next question unless they have chosen the specified number of responses. For example:

KeyPoints "From the following list
  what are the <b>two</b> main points
you consider when choosing a restaurant for a family celebration?"
categorical [2..2]
{
  Price, Location,
  ChildrenWelcome "Children are welcome",
  ChildMenu "Children's menus",
  FoodChoice "Wide choice of dishes",
  Vegetarian "Vegetarian options available on the main menu",
  SpecialDiet "Special diets catered for",
  Ambience "General feeling and ambience",
  NoSmoke "Non-smoking",
  AllowsSmoking "Smoking allowed"
};

If you do not specify the number of responses required, the interviewing program allows respondents to leave the question unanswered.

The usual method of setting up a multiple-choice response list is to specify the number of responses as [1..], meaning that one or more responses can be chosen. For example:

FoodLiked "What types of food do you like?" categorical [1..]
{
Indian, Chinese, Greek, Italian,
English, WestIndian "West Indian",
French, Thai, Japanese, Spanish,
Turkish, Other
};

You can specify the maximum number of responses that can be chosen from a multiple choice list by typing, for example:

UsuallyCook "When you cook for friends, which types of food do you
usually cook? Make up to three choices." categorical [..3]
{
Indian, Chinese, Greek, Italian, English,
WestIndian "West Indian",
French, Thai, Japanese, Spanish, Turkish,
Other
};

There is no minimum number of responses defined, so respondents can leave this question unanswered. If you want respondents to answer the question, specify a minimum number of choices, so most questions of this type specify a range such as [1..3].